1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:
15:
16:
17:
18:
19:
20:
21:
22:
23:
24:
25:
26:
27:
28:
29:
30:
31:
32:
33:
34:
35:
36:
37:
38:
39:
40:
41:
42:
43:
44:
45:
46:
47:
48:
49:
50:
51:
52:
53:
54:
55:
56:
57:
58:
59:
60:
61:
62:
63:
64:
65:
66:
67:
68:
69:
70:
71:
72:
73:
74:
75:
76:
77:
78:
79:
80:
81:
82:
83:
84:
85:
86:
87:
88:
89:
90:
91:
92:
93:
94:
95:
96:
97:
98:
99:
100:
101:
102:
103:
104:
105:
106:
107:
108:
109:
110:
111:
112:
113:
114:
115:
116:
117:
118:
119:
120:
121:
122:
123:
124:
125:
126:
127:
128:
129:
130:
131:
132:
133:
134:
135:
136:
137:
138:
139:
140:
141:
142:
143:
144:
145:
146:
147:
148:
149:
150:
151:
152:
153:
154:
155:
156:
157:
158:
159:
160:
161:
162:
163:
164:
165:
166:
167:
168:
169:
170:
171:
172:
173:
174:
175:
176:
177:
178:
179:
180:
181:
182:
183:
184:
185:
186:
187:
188:
189:
190:
191:
192:
193:
194:
195:
196:
197:
198:
199:
200:
201:
202:
203:
204:
205:
206:
207:
208:
209:
210:
211:
212:
213:
214:
215:

program Aufgabe20;
//Spielsteine werden Reihe für Reihe von links nach rechts belegt und getestet
{$IFDEF FPC}{$MODE DELPHI}{$ENDIF}
//{$R+,O+}
type
 tKoor = record
           zeile,spalte:byte;
         end;
 tSpielstein  = array[0..1,0..1] of byte;
 tpSpielstein  = ^tSpielstein;
 trow = array[0..7] of byte;
 tSpielfeld = array[0..7] of trow;
 tpRow = ^trow;
 tSpielFeldPos = array[0..15] of tKoor;
 tSpielsteine = array[0..15] of tSpielstein;
 tReihenfolge = array[0..15] of byte;
 tbelegt = array[0..15] of boolean;
var
  SpielFeld:tSpielFeld;
  SpielFeldPos :tSpielFeldPos;
  Spielsteine : tSpielsteine;
  Reihenfolge : tReihenfolge;
  belegt : tBelegt;

  gblCount : NativeInt;
  HabeFertig: Boolean;

procedure SwapElem(FeldNr,i:NativeInt);inline;
var
  tmp : byte;
begin
  tmp:= Reihenfolge[FeldNr];
  Reihenfolge[FeldNr]:= Reihenfolge[i];
  Reihenfolge[i] := tmp;
end;

procedure InitSpielsteine;
var
 i,row,col :NativeInt;
Begin
  fillchar(SpielSteine,SizeOf(SpielSteine),#0);
//Spielsteine[0]
  Spielsteine[1][0,0] := 1;
  Spielsteine[2][0,1] := 1;
  Spielsteine[3][1,0] := 1;
  Spielsteine[4][1,1] := 1;

  Spielsteine[5][0,0] := 1;
  Spielsteine[5][0,1] := 1;
  Spielsteine[6][0,0] := 1;
  Spielsteine[6][1,0] := 1;

  Spielsteine[7][0,0] := 1;
  Spielsteine[7][1,1] := 1;

  //invertieren
  For i := 8 to 15 do
    For row := 1 downto 0 do
      For col := 1 downto 0 do
        Spielsteine[i][row,col] := 1-Spielsteine[i-8][row,col];

  i := 0;
  //Auf welchem Platz wird ein Spielstein abgelegt ( linke obere Ecke )
  For row := 0 to 3 do
    For col := 0 to 3 do
    Begin
      with SpielFeldPos[i] do
      Begin
        zeile := 2*row;
        spalte := 2*col;
      end;
      inc(i);
    end;

  For i := 0 to 15 do
    Reihenfolge[i]:= i;
  randomize;
  For i := 15 downto 1 do
  Begin
    col:= random(i+1);
    SwapElem(i,col);
  end;

  HabeFertig := false;
  gblCount := 0;
end;

function TesteSpielStein(SpFdPos:NativeInt):boolean;
var
 pRow1,pRow2 :tpRow;
 row,col :NativeInt;
Begin
  result := true;

  with SpielFeldPos[SpFdPos] do
  begin
    row := zeile;
    col := spalte;
  end;
  pRow1 := @Spielfeld[row];
  //teste darueber, wenn nicht oberste Zeile
  If row >0 then
    Begin
      //pRow2:=@Spielfeld[row-1];
      pRow2 := pRow1;
      dec(pRow2);
      result := (pRow1^[col]=pRow2^[col]) AND (pRow1^[col+1] =pRow2^[col+1]);
      IF NOT(Result) then
        EXIT;
    end;

  //teste links, wen nicht linke Spalte
  If col>0 then
    Begin
    //pRow2:=@Spielfeld[row+1];
    pRow2 := pRow1;
    inc(pRow2);
    result := (pRow1^[col-1] =pRow1^[col]) AND (pRow2^[col-1] =pRow2^[col]);
  end;
end;

procedure SetzeSpielStein(SpFdPos:NativeInt;SpStNr:NativeInt);
var
 pSp:tpSpielstein;
 pRow :tpRow;
 col :NativeInt;
Begin
  pSp := @Spielsteine[SpStNr];
  belegt[SpFdPos]:= true;
  with SpielFeldPos[SpFdPos] do
  begin
    pRow := @Spielfeld[zeile];
    col := spalte;
  end;

  pRow^[col] := pSp^[0,0];
  pRow^[col+1] := pSp^[0,1];
  inc(pRow);
  pRow^[col] := pSp^[1,0];
  pRow^[col+1] := pSp^[1,1];
end;

procedure LoescheSpielStein(SpFdPos:NativeInt);
var
 pRow : tpRow;
 col :NativeInt;
Begin
  belegt[SpFdPos]:= false;
  with SpielFeldPos[SpFdPos] do
  begin
    pRow := @Spielfeld[zeile];
    col := spalte;
  end;
  pRow^[col] := 0;
  pRow^[col+1] := 0;
  inc(pRow);
  pRow^[col] := 0;
  pRow^[col+1] := 0;
end;

procedure Ausgabe;
var
  col,row :NativeInt;
  pRow : tpRow;
Begin
  pRow := @Spielfeld[0];
  For row := 0 to 7 do
  Begin
    iF Not(Odd(row)) then
      writeln;
    For col := 0 to 7 do
    begin
      iF Not(Odd(col)) then
        write('.');
      write(pRow^[col]);
    end;
    writeln;
    inc(pRow);
  end;
  writeln;
end;

procedure Rekurs(FeldNr:nativeInt);
var
  i : NativeInt;
Begin
  IF FeldNr <=  High(tSpielsteine) then
  Begin
    For i := FeldNr to High(tSpielsteine) do
    begin
      SwapElem(FeldNr,i);
      SetzeSpielStein(FeldNr,Reihenfolge[FeldNr]);
      IF TesteSpielStein(FeldNr) then
        Rekurs(FeldNr+1);
      LoescheSpielStein(FeldNr);
      SwapElem(FeldNr,i);
    end
  end
  else
  Begin
    inc(gblCount);
    IF NOT(Habefertig) then
    Begin
      Ausgabe;
      HabeFertig:= true;
    end;
  end;
end;

begin
  InitSpielsteine;
  Rekurs(0);
  Writeln('Es gibt ',gblCount,' Anordnungen');
  readln;
end.					

1:
2:
3:
4:
5:
6:
7:
8:
9:
10:
11:
12:
13:
14:

{ Eine moegliche Ausgabe }
.01.11.11.11
.10.00.01.10

.10.00.01.10
.10.00.00.00

.10.00.00.00
.01.11.10.01

.01.11.10.01
.01.11.11.11

Es gibt 800 Anordnungen